Управление созданием задач ознакомления в процессах согласования

Публикация № 1712099 18.08.22

Управленческий учет - Документооборот и делопроизводство

Расширение с настройками отключения задач ознакомления бизнес процесса согласование

Используя регистр настроек, отключаем задачи ознакомления для различных точек маршрута согласования.

Бывает необходимость при настройке шаблонов процессов 1С Документооборот 8 отключить задачи ознакомления, произведем данные действия с использованием регистра сведений для настроек и расширения для логики настроек. 

Начнем с добавления в основную конфигурацию справочника для хранения элементов настроек:

 

 

 

Далее добавим регистр настроек РАДО_НастройкиПроцессов:

 

 

ОбъектНастройки: СправочникСсылка.ВидыВнутреннихДокументов, СправочникСсылка.ШаблоныСогласования, СправочникСсылка.ВидыВходящихДокументов, СправочникСсылка.ШаблоныИсполнения, СправочникСсылка.ВидыИсходящихДокументов

Параметр: СправочникСсылка.РАДО_ПараметрыПроцессов

ЗначениеНастройки: Булево

В модуль менеджера регистра РАДО_НастройкиПроцессов добавим код с функцией получения параметров процессов:

Функция ПолучитьПараметрПроцесса(ОбъектНастройки, Параметр) Экспорт
	
	УстановитьПривилегированныйРежим(Истина);
	
	Запрос = Новый Запрос;
	Запрос.Текст = 
			"ВЫБРАТЬ
			|	РАДО_НастройкиПроцессов.ЗначениеНастройки КАК ЗначениеНастройки
			|ИЗ
			|	РегистрСведений.РАДО_НастройкиПроцессов КАК РАДО_НастройкиПроцессов
			|ГДЕ
			|	РАДО_НастройкиПроцессов.ОбъектНастройки = &ОбъектНастройки
			|	И РАДО_НастройкиПроцессов.Параметр = &Параметр";
	
	Запрос.УстановитьПараметр("ОбъектНастройки", ОбъектНастройки); 
	Запрос.УстановитьПараметр("Параметр", Параметр);	
	
	РезультатЗапроса = Запрос.Выполнить();
	
	Если РезультатЗапроса.Пустой() Тогда
		Возврат Неопределено;
	КонецЕсли;	
		
    ЗначениеПараметра = РезультатЗапроса.Выгрузить()[0].ЗначениеНастройки;
	
	Возврат ЗначениеПараметра;
	
КонецФункции	

Дальнейшие действия будем производить в расширении конфигурации.

Добавим в модуль объекта бизнес процесса согласование функцию ПолучитьПризнакОтключенияЗадачиОзнакомления, в ней будем в зависимости от результата согласования выбирать параметр, собирать массив предметов для анализа и передавая в функцию РАДО_УправлениеНастройками.ПолучитьПризнакОтключенияЗадачиОзнакомления определять необходимость отключения задач ознакомления:

Функция ПолучитьПризнакОтключенияЗадачиОзнакомления()
	
	Если РезультатСогласования = Перечисления.РезультатыСогласования.СогласованоСЗамечаниями Тогда		
		ПараметрПроцесса = Справочники.РАДО_ПараметрыПроцессов.БезОзнакомленияПриСогласованоСЗамечаниями;
	ИначеЕсли РезультатСогласования = Перечисления.РезультатыСогласования.НеСогласовано Тогда
		ПараметрПроцесса = Справочники.РАДО_ПараметрыПроцессов.БезОзнакомленияПриНеСогласовано;
	ИначеЕсли РезультатСогласования = Перечисления.РезультатыСогласования.Согласовано Тогда
		ПараметрПроцесса = Справочники.РАДО_ПараметрыПроцессов.БезОзнакомленияПриСогласовано;		
	Иначе 		
         Возврат Ложь;
	КонецЕсли;	
	
	МассивПредметовЗадачи = Новый Массив;
	
	Для Каждого СтрПредмет Из Предметы Цикл 
		Если ТипЗнч(СтрПредмет.Предмет) = Тип("СправочникСсылка.ВходящиеДокументы")
			Или ТипЗнч(СтрПредмет.Предмет) = Тип("СправочникСсылка.ИсходящиеДокументы")
			Или ТипЗнч(СтрПредмет.Предмет) = Тип("СправочникСсылка.ВнутренниеДокументы") Тогда
			МассивПредметовЗадачи.Добавить(СтрПредмет.Предмет);
		КонецЕсли
	КонецЦикла;			
	
	ОтключениеЗадачиОзнакомления = РАДО_УправлениеНастройками.ПолучитьПризнакОтключенияЗадачиОзнакомления(Шаблон, 
	ПараметрПроцесса,
	МассивПредметовЗадачи);
	
	Возврат ОтключениеЗадачиОзнакомления;
	
КонецФункции

Для процедур ОзнакомитьсяПередСозданиемЗадач, ЗавершениеПриЗавершении модуля объекта бизнес процесса согласование сделаем вставки с обращением к функции ПолучитьПризнакОтключенияЗадачиОзнакомления перед созданием задач: 

&ИзменениеИКонтроль("ОзнакомитьсяПередСозданиемЗадач")
Процедура РАДО_ОзнакомитьсяПередСозданиемЗадач(ТочкаМаршрутаБизнесПроцесса, ФормируемыеЗадачи, СтандартнаяОбработка)

	СтандартнаяОбработка = Ложь;

	// Если процесс завершился положительно, то задачу ознакомления формируем
	// после завершения процесса.
	Если РезультатСогласования = Перечисления.РезультатыСогласования.Согласовано Тогда
		Возврат;
	КонецЕсли;
	
	#Вставка
	Если ПолучитьПризнакОтключенияЗадачиОзнакомления() = Ложь Тогда
	#КонецВставки
		Задача = Задачи.ЗадачаИсполнителя.СоздатьЗадачу();
		ЗаполнитьЗадачуОзнакомиться(Задача);
		
		ЗадачаСсылка = Задачи.ЗадачаИсполнителя.ПолучитьСсылку();
		Задача.УстановитьСсылкуНового(ЗадачаСсылка);
		
		ФормируемыеЗадачи.Добавить(Задача);
		
		УстановитьПривилегированныйРежим(Истина);
		НоваяСтрока = РезультатыОзнакомлений.Добавить();
		НоваяСтрока.НомерИтерации 	  = НомерИтерации;
		НоваяСтрока.ЗадачаИсполнителя = ЗадачаСсылка;
		
		РаботаСБизнесПроцессами.ЗаписатьПроцесс(ЭтотОбъект, "ПростаяЗапись");		
	#Вставка
	КонецЕсли;
	#КонецВставки

КонецПроцедуры

&ИзменениеИКонтроль("ЗавершениеПриЗавершении")
Процедура РАДО_ЗавершениеПриЗавершении(ТочкаМаршрутаБизнесПроцесса, Отказ)

	УстановитьПривилегированныйРежим(Истина);
	ДатаЗавершения = ТекущаяДатаСеанса();

	СрокИсполненияДатой = ДатаЗавершения;

	РаботаСПроектами.ОтметитьОкончаниеВыполненияПроектнойЗадачи(ЭтотОбъект);

	// Если процесс завершился положительно и нет задачи ознакомления (задача ознакомления могла быть
	// создана до перехода на редакцию 2.1), то создаем задачу ознакомления с результатом.
	Если РезультатСогласования = Перечисления.РезультатыСогласования.Согласовано
	#Вставка
	    И ПолучитьПризнакОтключенияЗадачиОзнакомления() = Ложь
	#КонецВставки
		И РезультатыОзнакомлений.Найти(НомерИтерации, "НомерИтерации") = Неопределено Тогда
		
		Задача = Задачи.ЗадачаИсполнителя.СоздатьЗадачу();
		ЗаполнитьЗадачуОзнакомиться(Задача);
		Задача.Записать();

		НоваяСтрока = РезультатыОзнакомлений.Добавить();
		НоваяСтрока.НомерИтерации 	  = НомерИтерации;
		НоваяСтрока.ЗадачаИсполнителя = Задача.Ссылка;

		РаботаСБизнесПроцессами.ЗаписатьПроцесс(ЭтотОбъект, "ПростаяЗапись");

	КонецЕсли;
	
КонецПроцедуры

В общем модуле расширения РАДО_УправлениеНастройками отработаем анализ данных регистра настроек РАДО_НастройкиПроцессов функцией ПолучитьПараметрПроцесса:

Функция ПолучитьПараметрПроцесса(ОбъектНастройки, Параметр) Экспорт
	
	Возврат РегистрыСведений.РАДО_НастройкиПроцессов.ПолучитьПараметрПроцесса(ОбъектНастройки, Параметр);
	
КонецФункции

Добавим в общий модуль расширения РАДО_УправлениеНастройками функцию ПолучитьПризнакОтключенияЗадачиОзнакомления, в которой будем анализировать настройки шаблона и предметов процесса на необходимость отключения задач ознакомления:

Функция ПолучитьПризнакОтключенияЗадачиОзнакомления(Шаблон, ПараметрПроцесса, МассивПредметовЗадачи) Экспорт
	
	КолвоПредметов = МассивПредметовЗадачи.Количество();
	
	Если КолвоПредметов = 0 Тогда
		
		ОтключениеЗадачиОзнакомления = ПолучитьПараметрПроцесса(Шаблон, ПараметрПроцесса);
		
		Если ОтключениеЗадачиОзнакомления = Неопределено Тогда
			Возврат Ложь;
		Иначе 
			Возврат ОтключениеЗадачиОзнакомления;
		КонецЕсли;	
		
	Иначе
		
		Запрос = Новый Запрос;
		Запрос.УстановитьПараметр("Шаблон", Шаблон);
		Запрос.УстановитьПараметр("ПараметрПроцесса", ПараметрПроцесса);
		
		Если КолвоПредметов = 1 Тогда 		
			
			ПредметЗадачи = МассивПредметовЗадачи[0];
			ИмяТаблицыПредмета = ОбщегоНазначения.ИмяТаблицыПоСсылке(ПредметЗадачи);		
			МассивТекстовЗапроса = Новый Массив;
			
			ТекстЗапроса = 
			"ВЫБРАТЬ
			|	РАДО_НастройкиПроцессов.ЗначениеНастройки КАК ЗначениеНастройки
			|ИЗ
			|	РегистрСведений.РАДО_НастройкиПроцессов КАК РАДО_НастройкиПроцессов
			|ГДЕ
			|	РАДО_НастройкиПроцессов.ОбъектНастройки = &Шаблон
			|	И РАДО_НастройкиПроцессов.Параметр = &ПараметрПроцесса
			|;
			|
			|////////////////////////////////////////////////////////////////////////////////
			|ВЫБРАТЬ
			|	РАДО_НастройкиПроцессов.ЗначениеНастройки КАК ЗначениеНастройки
			|ИЗ
			|	РегистрСведений.РАДО_НастройкиПроцессов КАК РАДО_НастройкиПроцессов
			|		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ";
			
			МассивТекстовЗапроса.Добавить(ТекстЗапроса);
			МассивТекстовЗапроса.Добавить(ИмяТаблицыПредмета);	
			
			ТекстЗапроса = " КАК ТаблицаДокумента
			|		ПО (РАДО_НастройкиПроцессов.ОбъектНастройки = ТаблицаДокумента.ВидДокумента
			|				И ТаблицаДокумента.Ссылка = &ПредметЗадачи
			|				И РАДО_НастройкиПроцессов.Параметр = &ПараметрПроцесса)";			
			
			МассивТекстовЗапроса.Добавить(ТекстЗапроса);
			Запрос.Текст = СтрСоединить(МассивТекстовЗапроса);
			
			Запрос.УстановитьПараметр("ПредметЗадачи", ПредметЗадачи);			
			
			РезультатПакет = Запрос.ВыполнитьПакет();
			
			РезультатЗапросаШаблона = РезультатПакет[0];
			РезультатЗапросаПредметов = РезультатПакет[1];
			
		Иначе 		
						
			СоответствиеТиповПредметов = Новый Соответствие;
			
			Для Каждого Предмет Из МассивПредметовЗадачи Цикл 
				
				ТипПредмета = ТипЗнч(Предмет);
				
				МассивПредметовТипа = СоответствиеТиповПредметов.Получить(ТипПредмета);
				
				Если МассивПредметовТипа = Неопределено Тогда
					МассивПредметовТипа = Новый Массив;
					МассивПредметовТипа.Добавить(Предмет);
					СоответствиеТиповПредметов.Вставить(ТипПредмета, МассивПредметовТипа);
				Иначе 
					МассивПредметовТипа.Добавить(Предмет);
				КонецЕсли;	
				
			КонецЦикла;  												
			
			МассивТекстовЗапроса = Новый Массив;
			
			НомерЗапроса = 1;
			
			ТекстЗапроса = "ВЫБРАТЬ
			|	РАДО_НастройкиПроцессов.ЗначениеНастройки КАК ЗначениеНастройки
			|ИЗ
			|	РегистрСведений.РАДО_НастройкиПроцессов КАК РАДО_НастройкиПроцессов
			|ГДЕ
			|	РАДО_НастройкиПроцессов.ОбъектНастройки = &Шаблон
			|	И РАДО_НастройкиПроцессов.Параметр = &ПараметрПроцесса";
			МассивТекстовЗапроса.Добавить(ТекстЗапроса);
			
			Для Каждого ТипПредмета Из СоответствиеТиповПредметов Цикл 
				
				Если НомерЗапроса = 1 Тогда
					ТекстЗапроса = "
					|;
					|
					|////////////////////////////////////////////////////////////////////////////////";
				Иначе 	
					ТекстЗапроса = 	"
					|
					|ОБЪЕДИНИТЬ ВСЕ
					|";
				КонецЕсли;	
				
				МассивТекстовЗапроса.Добавить(ТекстЗапроса);				
				ИмяТаблицыПредмета = ОбщегоНазначения.ИмяТаблицыПоСсылке(ТипПредмета.Значение[0]);				
				ИмяПараметраПредметов = "ПредметыПроцесса" + Формат(НомерЗапроса, "ЧГ=0");
				
				Если НомерЗапроса = 1 Тогда
					ТекстЗапроса = "	
					|ВЫБРАТЬ
					|	ЕСТЬNULL(РАДО_НастройкиПроцессов.ЗначениеНастройки, ЛОЖЬ) КАК ЗначениеНастройки
					|ПОМЕСТИТЬ ВР_НастройкиПроцессов
					|ИЗ
					|	";					
				Иначе 
					ТекстЗапроса = "	
					|ВЫБРАТЬ
					|	ЕСТЬNULL(РАДО_НастройкиПроцессов.ЗначениеНастройки, ЛОЖЬ) КАК ЗначениеНастройки
					|ИЗ
					|	";
											
				КонецЕсли;
								
				МассивТекстовЗапроса.Добавить(ТекстЗапроса);				
				МассивТекстовЗапроса.Добавить(ИмяТаблицыПредмета);				
				
				ТекстЗапроса =
				" КАК ТаблицаПредмета
				|	ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.РАДО_НастройкиПроцессов КАК РАДО_НастройкиПроцессов
				|		ПО РАДО_НастройкиПроцессов.ОбъектНастройки = ТаблицаПредмета.ВидДокумента
				|				И РАДО_НастройкиПроцессов.Параметр = &ПараметрПроцесса
				|ГДЕ
				|	ТаблицаПредмета.Ссылка В (&";
				
				МассивТекстовЗапроса.Добавить(ТекстЗапроса);
				МассивТекстовЗапроса.Добавить(ИмяПараметраПредметов);
				МассивТекстовЗапроса.Добавить(")");
				
				НомерЗапроса = НомерЗапроса + 1;
				
				Запрос.УстановитьПараметр(ИмяПараметраПредметов, ТипПредмета.Значение);
				
			КонецЦикла;					
			
			ТекстЗапроса = "
			|;
			|
			|////////////////////////////////////////////////////////////////////////////////
			|ВЫБРАТЬ
			|	МИНИМУМ(ВР_НастройкиПроцессов.ЗначениеНастройки) КАК ЗначениеНастройки
			|ИЗ
			|	ВР_НастройкиПроцессов КАК ВР_НастройкиПроцессов";
				
			МассивТекстовЗапроса.Добавить(ТекстЗапроса);	
			
			Запрос.Текст = СтрСоединить(МассивТекстовЗапроса);
			
			РезультатПакет = Запрос.ВыполнитьПакет();
			
			РезультатЗапросаШаблона = РезультатПакет[0];
			РезультатЗапросаПредметов = РезультатПакет[2];			
			
		КонецЕсли;
		
		Если РезультатЗапросаШаблона.Пустой() Тогда
			Если РезультатЗапросаПредметов.Пустой() Тогда
				ОтключениеЗадачиОзнакомления = Ложь; 				
			Иначе 
				ОтключениеЗадачиОзнакомления = РезультатЗапросаПредметов.Выгрузить()[0].ЗначениеНастройки;
				Если ОтключениеЗадачиОзнакомления = Null Тогда
					Возврат Ложь;
				Иначе 	
					Возврат ОтключениеЗадачиОзнакомления;
				КонецЕсли;	
			КонецЕсли  				   				
		Иначе
			ОтключениеЗадачиОзнакомления = РезультатЗапросаШаблона.Выгрузить()[0].ЗначениеНастройки;			
		КонецЕсли;					
		
	КонецЕсли; 		
	
	Возврат ОтключениеЗадачиОзнакомления;
	
КонецФункции

Тестирование проводилось на платформе 8.3.18.1334 и конфигурации Документооборот 8 КОРП, редакция 2.1 (2.1.29.18).

Причины купить

Экономия времени т.к. не придется самостоятельно разрабатывать данный механизм при потребности.

Достоинства

Расширение с отключением задач ознакомления по настройкам процессов.

Скачать файлы

Наименование Файл Версия Размер
Управление созданием задач ознакомления в процессах:

.cfe 10,43Kb
1
.cfe 10,43Kb 1 Скачать

Специальные предложения

Оставьте свое сообщение

См. также

Конструктор печатных форм для ЗУП 3.1 по шаблонам MSOffice и OpenOffice Промо

Печатные формы Документооборот и делопроизводство Платформа 1С v8.3 Сложные периодические расчеты 1С:Зарплата и Управление Персоналом 3.x Абонемент ($m)

Данная обработка позволяет быстро создавать печатные формы документов на основании документов из программы 1С ЗУП8 версии 3.1. Печатные формы можно заполнять на основании следующих документов: "Прием на работу", "Прием на работу списком", "Кадровый перевод", "Кадровый перевод списком", "Перемещение в другое подразделение", "Договор ГПХ" Обработка протестирована на платформе 1С:Предприятие 8.3 (8.3.12.1714) релиз ЗУП 3.1.9.187 Тонкий клиент (файловый или клиент-сервер) Установленный Microsoft office (2003 и выше) или OpenOffice/LibreOffice 09/04/2019 Исправил ошибку, возникающую, если наименование вида расчета содержит скобки.

10 стартмани

02.11.2017    34920    309    zabaluev    62    

Параметризация печатных форм под контрагентов (подключаемое расширение)

Печатные формы Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Расширение добавляет возможности параметризации печати для контрагентов. Подробнее описано здесь https://infostart.ru/1c/articles/1510459/

10 стартмани

05.08.2022    4206    4    sapervodichka    4    

Просмотр объектов очереди сообщений в 1С:Документооборот

Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

В базах с бесшовной интеграцией с 1С:Документооборот есть Регистр сведений "Очередь сообщений в 1С:Документооборот". Для пользователя он мало информативен. Расширение позволяет просматривать сообщение в человеческом виде. И понимать проблему до объекта.

1 стартмани

02.08.2022    4088    13    sapervodichka    4    

Выгрузка документов в формате XML для загрузки в ЭДО операторов СБИС, Диадок и т.п.

Адаптация типовых решений Файловые протоколы обмена (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:ERP Управление предприятием 2 Россия Абонемент ($m)

Расширение для добавления дополнительного функционала в библиотеку БЭД , добавляет команду для выгрузки данных в формате XML для загрузки в ЭДО из 1С.

3 стартмани

30.06.2022    1364    13    osa92    7    

Печать конвертов из 1С Промо

Пакетная печать Документооборот и делопроизводство Платформа 1С v8.3 Конфигурации 1cv8 Россия Абонемент ($m)

Внешняя печатная форма для печати конвертов формата C4 и C5. Печать с полной разметкой почтового конверта и размещением адресов отправителя и получателя, включая индекс.

1 стартмани

07.12.2015    39218    22    sashs1980    32    

Критерии отбора в расширении. 16+

Адаптация типовых решений Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 1С:Комплексная автоматизация 2.х Абонемент ($m)

Связываем критерии отбора расширения с типовой структурой подчиненности в универсальных решениях 1С.

3 стартмани

09.06.2022    2660    16    Ankare    10    

Обезжиривание шрифта в печатной форме (экономим тонер)

Печатные формы Адаптация типовых решений Платформа 1С v8.3 1С:Бухгалтерия 3.0 Абонемент ($m)

Код, который убирает полужирное начертание у шрифтов в печатной форме. Тестировалось на конфигурации Бухгалтерия Предприятия 3.0.111.16. Но должно работать на любых конфигурациях с БСП.

1 стартмани

24.05.2022    1318    1    q_i    4    

Присоединение внешней печатной формы в виде файла к объекту-основанию

Печатные формы Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

В данной публикации речь пойдёт о том, как можно присоединить сформированную внешнюю печатную форму в виде файла к тому объекту (справочнику, документу и т.п.), на основании которого она была сформирована.

1 стартмани

20.05.2022    1799    1    delta    0    

Обработка "Распознавание штрихкода с помощью утилиты Zbar" для Документооборот ред. 2 Промо

Универсальные обработки Документооборот и делопроизводство Платформа 1С v8.3 1С:Документооборот Абонемент ($m)

В связи с тем, что стандартный функционал программы «Документооборот» ред. 2.1 дает возможность распознавания штрихкодов только форма EAN-13, данная обработка - альтернативный способ для распознавания штрихкода в программе 1С: Документооборот ред. 2 с помощью утилиты Zbar, которая распознает в том числе и в формате Code 128 (один из стандартных штрихкодов кодирования документов, например, «Управление торговлей» ред. 11), а также с возможностью поэтапно проследить все действия от распознавания до прикрепления к документу или простой загрузки в каталоги файлов в базе 1С.

5 стартмани

05.09.2016    32400    192    SEOAngels    11    

Добавление состояния согласования из 1С: Документооборот

Документооборот и делопроизводство Адаптация типовых решений Платформа 1С v8.3 1С:Документооборот Абонемент ($m)

Добавляем статус согласования из подключенной базы 1С Документооборот в типовые и нетиповые конфигурации с использованием библиотеки интеграции с 1С: Документооборотом. Статусы добавляются в формы списка и формы объектов.

1 стартмани

11.05.2022    2187    1    Free_Danial    0    

Автозаполнение шаблонов файлов MXL в "1С:Документообороте"

Документооборот и делопроизводство Адаптация типовых решений Платформа 1С v8.3 1С:Документооборот Абонемент ($m)

Добавление возможности создавать автозаполняемые шаблоны файлов в формате MXL в 1С:Документооборот и сохранением заполненного файлы в формате PDF (таблицы, результаты запроса реквизиты...)

1 стартмани

05.05.2022    2504    11    JIEX@    0    

Хранение файлов в томах на диске (для УПП 1.3) Промо

Адаптация типовых решений Платформа 1С v8.3 1С:Управление производственным предприятием Абонемент ($m)

Доработка типовой УПП 1.3 в плане хранения присоединенных файлов вне базы данных

2 стартмани

05.06.2016    75821    20    wowik    33    

Выгрузка УПД в формате XML в Контур Диадок из 1С:УПП, УТ 10, БП 3.0

Документооборот и делопроизводство Файловые протоколы обмена (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:Управление торговлей 10 1С:Управление производственным предприятием Бухгалтерский учет Абонемент ($m)

Выгрузка в формате XML документов УПД для загрузки в Контур Диадок. В соответствии с Приказом ФНС России от 19.12.2018 № ММВ-7-15/820@  в редакции постановления № 543 от 2 апреля 2021 г.

5 стартмани

22.03.2022    5244    63    AlexsVola    42    

Оповещение по почте о документах

Документооборот и делопроизводство Email рассылки Платформа 1С v8.3 Конфигурации 1cv8 Россия Абонемент ($m)

Рассылка писем со ссылками на документы, удовлетворяющие установленному отбору.

1 стартмани

14.02.2022    2585    2    victorree    0    

Реализация с кодами маркировки через ЭДО в Рознице 2.3

Оптовая торговля Розничная торговля Документооборот и делопроизводство WEB-интеграция Платформа 1С v8.3 1С:Розница Россия Абонемент ($m)

Расширение для возможности формировать и отправлять через ЭДО УПД с маркированными товарами по документу "Реализация".

2 стартмани

27.01.2022    3423    34    boba13    30    

Приемная руководителя, редакция 1.1 Промо

Документооборот и делопроизводство Платформа 1С v8.3 Абонемент ($m)

Приемная руководителя, редакция 1.1. Конфигурация на управляемых формах (интерфейс - Такси) с открытым кодом, создана для секретарей.

1500 руб.

19.05.2015    33065    22    10    

Отображение проблем синхронизации с Документооборотом 2.1

Документооборот и делопроизводство Платформа 1С v8.3 1С:Документооборот Управленческий учет Абонемент ($m)

Внешний отчет для Документооборот 2.1, основанный на анализе регистра сведений Сведения о сообщениях обмена с интегрированными системами. Можно использовать для сигнализации о проблемах остановки обмена.

1 стартмани

02.01.2022    2918    4    ardn    0    

Программное создание и расчет документов начисления зарплаты в конфигурации ЗУП 3.1 и ERP (по подразделениям)

Зарплата Адаптация типовых решений Платформа 1С v8.3 Сложные периодические расчеты 1С:ERP Управление предприятием 2 1С:Зарплата и Управление Персоналом 3.x Бухгалтерский учет Абонемент ($m)

Краткое описание типового механизма расчета зарплаты в конфигурации ЗУП 3.1 и ERP и описание разработанной обработки по программному расчету документов зарплаты в разрезе подразделений. Т.к. формирование документов происходит полностью программно, с минимумов параметров, его можно брать за основу для расчета документов по своим условиям, вплоть до создания по расписанию при необходимости.

10 стартмани

27.12.2021    5044    9    maraty    39    

Инструменты разработчика для работы с ЭДО СБИС ExtSdk2

Оптовая торговля Документооборот и делопроизводство Платформа 1С v8.3 Конфигурации 1cv8 Россия Абонемент ($m)

Несколько обработок, которые помогут разработчикам в автоматизации рабочих мест бухгалтеров и менеджеров продаж.

1 стартмани

25.12.2021    3647    18    bobylev1980    4    

Реестр договоров для 1С:Бухгалтерии Промо

Обработка документов Обработка справочников Документооборот и делопроизводство Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Абонемент ($m)

Реестр договоров для 1С:Бухгалтерии - дополнительная обработка для конфигурации "Бухгалтерия предприятия", версия 3.0

5 стартмани

28.10.2014    55788    118    RespectSoft    24    

БСП 3.1.5 Форма отчета. Быстрый вызов редактирования варианта

БСП (Библиотека стандартных подсистем) Адаптация типовых решений Работа с интерфейсом Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

В последних релизах современных конфигураций, основанных на БСП версии 3.1.5, спрятали кнопку настройки варианта в дебри вложенных форм. Вернём всё как было, и даже лучше.

1 стартмани

20.12.2021    4073    1    the1    0    

Доработка документа для формирования проводок в регламентированном учете ERP

Адаптация типовых решений Платформа 1С v8.3 1С:ERP Управление предприятием 2 1С:Управление торговлей 11 Бухгалтерский учет Абонемент ($m)

Статья о том, как включить разработанный документ в подсистему формирования проводок в конфигурации ERP

1 стартмани

17.12.2021    6014    5    maraty    6    

Работа с API Диадок

Документооборот и делопроизводство WEB-интеграция Платформа 1С v8.3 1С:Документооборот Абонемент ($m)

Обработка написана для конфигурации Документооборот, затрагивает самые основные методы работы с api Диадок.

5 стартмани

17.12.2021    3393    30    diar01    4    

Создание внешней печатной формы под Управляемое Приложение (Управление Торговлей 11.1.1.11) Промо

Адаптация типовых решений Универсальные функции Платформа 1С v8.3 1С:Управление торговлей 11 Россия Абонемент ($m)

Создание внешней печатной формы под Управляемое Приложение (Управление Торговлей 11.1.1.11)

1 стартмани

28.03.2013    162879    548    Stradivari    31    

Обновление МДЛП - проблемы с перемещением (431 сообщение)

Склад и ТМЦ Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Фармацевтика, аптеки Россия Управленческий учет Абонемент ($m)

Исправление ошибки с получением квитанции о перемещении МДЛП ("Мониторинг движения лекарственных препаратов для медицинского применения от производителя до конечного потребителя").

1 стартмани

24.11.2021    4186    2    Vladimir45    9    

Отображение ОГРН в карточке контрагента. УТ 11

Обработка справочников Адаптация типовых решений Платформа 1С v8.3 1С:Управление торговлей 11 Россия Абонемент ($m)

Возможность заполнения и отображения уже заполненного ОГРН из сервиса 1С:Контрагенты (расширение).

1 стартмани

11.11.2021    2237    5    pridecom    0    

Устранение проблемы с правами доступа. Документооборот КОРП 2.1

Документооборот и делопроизводство Роли и права Платформа 1С v8.3 1С:Документооборот Абонемент ($m)

Обработка позволяет открыть доступ для пользователей в конфигурации 1С: Документооборот КОРП 2.1, связанных с отсутствием необходимых записей в регистрах сведений СоставСубъектовПравДоступа и ПользователиВКонтейнерах. Проблема выражается в отсутствии доступа к папкам внутренних документов и непосредственно внутренним документам (см.рисунок).

1 стартмани

01.11.2021    4254    18    baturo    2    

Учет канцтоваров для секретаря - тонкий клиент (без информационной базы, на файлах excel) Промо

Документооборот и делопроизводство Универсальные обработки Загрузка и выгрузка в Excel Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Обработка включает для каждого файла загрузки из excel новую колонку в табличное поле обработки (управляемая форма, тонкий клиент), рассчитывает и выводит общие итоги. Табличку на тонком клиенте выводит в табличный документ. Обработка не использует информационную базу и независима от её структуры, только файлы эксель. Результат объединения тоже сохраняется в файл.

1 стартмани

11.09.2012    25857    22    ksnik    10    

Распознавание текста с использованием OCR Tesseract

Документооборот и делопроизводство Платформа 1С v8.3 1С:Документооборот Россия Абонемент ($m)

В 1С:Документооборот полнотекстовый поиск по содержимому отсканированных документов возможен, но не так хорош, как бы хотелось. Всё дело в качестве распознавания сканов. Поднимаем процесс распознавания на новую высоту с использованием Xpdf и OCR Tesseract.

5 стартмани

17.10.2021    4802    13    soulner    2    

Управление пользователями в документообороте

Документооборот и делопроизводство Роли и права Платформа 1С v8.3 1С:Документооборот Россия Абонемент ($m)

Обработка "Управление пользователями в документообороте" позволяет создавать новых пользователей и обновлять права у текущих пользователей. Возможно назначать права группе пользователей и пакетно создавать пользователей с одинаковыми правами. Облегчает рутинную работу при регулярной работе с правами пользователей.

1 стартмани

13.10.2021    4192    21    Smikle    0    

Преобразование doc/docx в PDF для 1С: Документооборот 8 КОРП, ПРОФ, ДГУ через обработчик бизнес-событий

Документооборот и делопроизводство Платформа 1С v8.3 1С:Документооборот Абонемент ($m)

Обработчик после регистрации нужного вида документа выполняет конвертацию файлов, прикрепленных к внутреннему документу формата doc/docx, в формат PDF и добавляет эти файлы к документу. Не требует изменений в конфигурации.

1 стартмани

05.10.2021    5374    4    vashkostya    1    

Согласование документов 1С:Документооборот и 1С:Консолидация из Outlook 2010-2013 без запуска 1С (с исходниками) Промо

Документооборот и делопроизводство Управление проектом Платформа 1С v8.3 1С:Документооборот Россия Управленческий учет Абонемент ($m)

Надстройки для Outlook 2010-2013, позволяющие пользователю без запуска 1С оперативно выполнять согласование документов при поступлении оповещения на электронную почту. Поддерживается интеграция с 1С:Документооборот ПРОФ и КОРП (работа с процессом "Согласование" с поддержкой просмотра файлов по внутренним и исходящим документам) и 1С:Консолидация ПРОФ (согласование "Заявок на расходование средств" и "Экземпляров отчетов" с возможностью просмотра печатных форм).

1 стартмани

16.07.2012    85969    427    Aleksey.Bochkov    123    

Проверка настройки заполнения для скриптов 1С:Документооборот

Документооборот и делопроизводство Корректировка данных Платформа 1С v8.3 1С:Документооборот Абонемент ($m)

Доброго времени суток, коллеги. После обновления базы 1С:Документооборот , при проверке заполнения файла по шаблону вылезла ошибка "Следующие реквизиты или скрипты настройки заполнения файла заданы не корректно:...". Захотел узнать, какие ещё скрипты заполнены не корректно. Написал обработку для проверки и исправления всех скриптов.

1 стартмани

19.09.2021    4908    12    Andrei_Ivanov    6    

Загрузка данных из внешних файлов для управляемых форм

Загрузка и выгрузка в Excel Адаптация типовых решений Платформа 1С v8.3 Конфигурации 1cv8 Абонемент ($m)

Простая и удобная обработка загрузки из файлов формата Excel, dbf и csv для конфигураций на управляемых формах (без модальности). Встраивается в любую конфигурацию (на управляемых формах) в любое место, где нужна загрузка из файлов.

2 стартмани

29.08.2021    4069    19    ALBA2009    2    

Где баланс между производительностью и возможностями программы ? Исправление автоподбора контрагента в УНФ

Рефакторинг и качество кода HighLoad оптимизация Адаптация типовых решений Платформа 1С v8.3 1С:Управление нашей фирмой Россия Управленческий учет Абонемент ($m)

Как и у многих ко мне стали поступать обращения от менеджеров о медленной работе 1с (эта ваша один с не дает нормально работать), и чтоб быть объективным, и не основываться на человеческом, субъективном восприятии решил вооружиться цифрами, а именно произвести анализ медленных запросов, и проблема была найдена, где я ее не ожидал.

1 стартмани

27.08.2021    4402    0    con-men    0    

[Расширение] Несколько касс ККМ в РМК для Розницы 2.3

Розничная торговля ККМ Рабочее место Адаптация типовых решений Платформа 1С v8.3 1С:Розница Абонемент ($m)

Расширение добавляет возможность добавлять и работать с несколькими кассами ККМ при продаже через РМК с одного рабочего места

1 стартмани

27.08.2021    5129    39    Nonik    55    

Формирование XML документа (УПД, счет, накладная, СФ и прочее)

Документооборот и делопроизводство Файловые протоколы обмена (TXT, XML, DBF), FTP Платформа 1С v8.3 1С:Бухгалтерия 3.0 1С:Управление торговлей 11 Россия Абонемент ($m)

С помощью этого кода для документов базы формируется XML-файл, который можно отправить через ЭДО СБИС, Диадок и пр. Поддерживается все форматы, которые поддерживает библиотека БЭД.

1 стартмани

24.08.2021    5110    81    blackhorse1976    10    

Отправка сообщений пользователям Промо

Адаптация типовых решений Платформа 1С v8.3 1С:Управление торговлей 10 Россия Абонемент ($m)

Предполагаю, что в организациях, где работает больше 10-15 человек, сложно звонить каждому и сообщать пользователям какую-либо информацию. Я обыскал на всех ресурсах, так того, что требуется, не нашел.

1 стартмани

13.01.2012    19593    374    kojinandrej    54    

Учет медосмотров, прививок, и приемов медицинских специалистов

Адаптация типовых решений Кадровый учет Платформа 1С v8.3 1С:Зарплата и Управление Персоналом 3.x Здравоохранение, медицина, стоматология Россия Абонемент ($m)

Расширение для ЗУП 3.1, предназначенное для ввода данных медперсоналом по медобследованиям сотрудников организации.

1 стартмани

23.08.2021    4202    20    user767823    6    

Обмен УТ 11 (11.4.13.227) с БП 3.0 (из серии - никогда такого не было, и вот опять)

Обмен между базами 1C Адаптация типовых решений Платформа 1С v8.3 1С:Управление торговлей 11 Россия Абонемент ($m)

После обновления на редакцию Управление торговлей, редакция 11 (11.4.13.227) перестал работать обмен с конфигурацией Бухгалтерия предприятия, редакция 3.0. Расширение конфигурации, исправляющее эту ошибку.

2 стартмани

28.07.2021    11301    50    capitan    21    

Прослеживаемость товара в Диадок (РНПТ). Подключаемый модуль для в УПП 1.3, УТ 10.3

Документооборот и делопроизводство Оптовая торговля Платформа 1С v8.3 1С:Управление торговлей 10 1С:Управление производственным предприятием Бухгалтерский учет Абонемент ($m)

С июля 2021 года введена прослеживаемости товаров с передачей данных через ЭДО. На данный момент в модуле Диадок (5.42.10) не реализовано заполнение РНПТ, и предлагаемый подключаемый модуль решает эту проблему.

1 стартмани

21.07.2021    5748    37    itmind    6    

Доработка Диадок для 1С. Заполнение графы 5а в УПД (с 01.07.2021). Подключаемый модуль

Документооборот и делопроизводство Оптовая торговля Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Абонемент ($m)

С 1 июля 2021 года действует новая форма УПД, такое изменение принято постановлением №534 от 02.04.2021 г. Правительством Российской Федерации. В форме УПД в данной редакции появилась графа 5а. Мне так и не удалось разобраться - обязательна она к заполнению или нет - в типовой форме в 1С:Бухгалтерия она заполняется, а в Диадок - нет. И было бы пофиг, но некоторые наши клиенты отказались принимать УПД с прочерком в строке 5а. Служба поддержки Диадок сообщила, что заполнение - не является обязательным, доработка - платная, тикет - закрыт :) Поэтому здесь Вы можете скачать Подключаемый модуль для Диадок, который заполняет графу 5а - Документы основания.

1 стартмани

06.07.2021    16750    132    AlxPop    38    

Розница 2.2, 2.3 выбор продавца из справочника Физ. лица перед входом в РМК с возможностью выбора кто будет отображаться в Чеке

Кассовые операции Розничная торговля Адаптация типовых решений Платформа 1С v8.3 1С:Розница Абонемент ($m)

Розница 2.2, 2.3 выбор продавца из справочника Физ. лица перед входом в РМК с возможностью выбора кто будет отображаться в Чеке

1 стартмани

22.06.2021    5120    12    andrey7617    2    

Если после обновления Розницы на версию 2.3.9.22 или более позднюю не определяются марки и некорректно работает сканер штрихкода

Розничная торговля Сканер штрих-кода Адаптация типовых решений Платформа 1С v8.3 1С:Розница Россия Абонемент ($m)

Если после обновления Розницы на релиз 2.3.9.22 или более позднюю. не работает сканер штрихкода версии 10.1.1.1, во вложении - драйвер сканера штрихкода версии 9.0.8.10 и расширение для тех у кого не устанавливается драйвер.

1 стартмани

21.06.2021    14724    211    санясоку    37    

Формирование файла типа xml для формализованных электронных передаточных и корректировочных документов и неформализованного электронного документа Счет на основании документа бухгалтерии

Документооборот и делопроизводство Файловые протоколы обмена (TXT, XML, DBF), FTP Платформа 1С v8.3 Бухгалтерский учет 1С:Бухгалтерия 3.0 Россия Бухгалтерский учет Налоговый учет НДС Абонемент ($m)

Обработка служит для формирования файла типа xml для следующих формализованных документов: счета-фактуры (СЧФ), документа об отгрузке товаров (выполнении работ), передаче имущественных прав (документа об оказании услуг) (ДОП), универсального передаточного документа (СЧФДОП-УПД), корректировочного счета-фактуры (КСЧФ), документа, подтверждающего согласие (факт уведомления) покупателя на изменение стоимости отгруженных товаров (выполненных работ, оказанных услуг), переданных имущественных прав (ДИС), универсального корректировочного документа (КСЧФДИС-УКД) и неформализованного документа Счет на основании документа, созданного в 1С: Бухгалтерия предприятия БП 3.0 для последующей загрузки на сайт оператора электронного документооборота. После загрузки файла на сайт можно при необходимости скорректировать документ и отправить его на согласование или подпись. Формализованные документы формируются по формату, утвержденному приказом ФНС России от 19.12.2018 г.№ ММВ-7-15/820@ и приказом ФНС России от 12.10.2020 г. № ЕД-7-26/736@ Прослеживаемые товары обрабатываются в соответствие с форматом ФНС, обработка маркированных товаров не реализована.

5 стартмани

28.05.2021    8151    43    fxfan    11    

Подсистема "Пользовательские автоподстановки" для 1С: Документооборот 2.1

Документооборот и делопроизводство Анализ и проектирование ИТ-систем Платформа 1С v8.3 1С:Документооборот Россия Управленческий учет Абонемент ($m)

Подсистема позволяет описать собственные алгоритмы автоподстановок исполнителей задач бизнес-процессов. Механизмы подсистемы может использовать любой компетентный пользователь/программист.

1 стартмани

12.05.2021    6359    20    Lok`Tar    16    

Адресная книга для 1С:Документооборот

Документооборот и делопроизводство Платформа 1С v8.3 1С:Документооборот Абонемент ($m)

Реализация через http-сервис публикации адресной книги для документооборота.

1 стартмани

27.04.2021    8495    3    SaschaG    8