Парсер запросов 1С. Часть 1: Введение, разбор математических выражений

Публикация № 239061

Разработка - Математика и алгоритмы

Парсер теория компиляторов запросы

Рано или поздно становится скучно решать типичные задачи, для которых придумана 1С. Голова пухнет от бухгалтерских терминов и очередных "хотелок" пользователей. Именно в такие моменты хочется гордо поднять голову, воскликнуть "Но я же программист!" и заняться чем-то интересным. В цикле статей я постараюсь доступно описать, как устроены парсеры в целом и на примере парсера языка запросов 1С. Требования к навыкам читающего: основы языка 1С, основы алгоритмизации.

Для начала, определю цели данной серии публикаций.

  1. Создание функции, выполняющей полноценный парсинг запросов 1С в некоторую древовидную структуру.
  2. Создание функции, выполняющей обратное преобразование
  3. Создание обработки "Конструктор запросов" на управляемых формах

Основную актуальность составляет именно третья задача, так как встроенный конструктор запросов работает только в толстом клиенте, а также не является обработкой с открытым кодом - вносить в него изменения невозможно. На инфостарте мелькали публикации с парсерами запросов, но во-первых не рассматривалась методика, а во-вторых я еще не видел парсера, который был бы полностью идентичен встроенному парсеру 1С по функциональности.

Также следует определить требования к парсеру:
  1. Он должен быть однопроходным (т.к. грамматика языка запросов не предполагает необходимости двупроходной обработки, как, например, грамматика языка C++)
  2. Он должен включать в себя лексический и синтаксический анализ. В перспективе необходима разработка тонкого анализа связи с метаданными конфигурации (семантический анализ).
  3. Он должен адекватно обрабатывать исключения

В первой части статьи я опишу разбор математических выражений. Эта тема очень хорошо освещена в русской и зарубежной литературе, впервые я познакомился с ней в книге "О чем не пишут в книгах по Delphi". На хабре достатоно поискать по ключевым словам "Парсер" или "Теория компиляторов". Более того, в данное время существуют генераторы парсеров, которые на основе данных о грамматике языка составляют исходный код парсера (Вики: Сравнение генераторв парсеров (англ.)). Однако, этот метод я рассматривать не буду - настоящий 1С-ник должен полагаться только на свой код.

Итак, какие же знания требуются для написания парсера?

Формальные грамматики.

Для описания грамматики языка Алгол Джоном Бэкусом и Питером Науром была раработана формальная система описания синтаксиса. Она называется БНФ (Бэкуса-Наура форма, BNF Вики: Форма Бэкуса-Наура). Данная система позволяет описывать одни категории с использованием других, постепенно наращивая сложность, и ее вполне реально использовать для решения поставленной задачи. Забегая вперед, скажу, что сама фирма 1С описывает свой язык запросов с помощью этой грамматики. Чтобы в этом убедиться, достаточно открыть справку по языку запросов.

Следующие операторы используются в БНФ:

::=

присваивание

|

Операция ИЛИ

 Имя

Литерал

[Имя]

Необязательный литерал

(Имя)

Литерал, повторяющийся 0 или более раз

При описании грамматики БНФ сначала необходимо дать определение абстракции нижнего уровня:

Цифра :: = '0' | '1' | '2' | '3' | '4' | '5' | '6' | '7' | '8' | '9'

С помощью этого выражения мы указываем, что литерал может принимать одно из значений '0' ... '9'

Абстракция более выского уровня - вещественное число:

Знак ::= '-' | '+'

Разделитель ::= '.'

Число ::= [Знак] Цифра (Цифра) [ Разделитель (Цифра) ]

Число может иметь знак (+, -) а может не иметь его. Далее должна идти хотя бы одна цифра (или более). Затем может идти разделитель дробной и целой части (а может не идти). Если есть разделитель, то далее может идти одна цифра (или более) (спасибо (9)) .

Простейшее математическое выражение должно удовлетворять следующим требованиям:

  1. Допустимы операции + - * /
  2. Приоритет операций: Скобка > Умножение = Деление > Сложение = Вычитание

Основную сложность представляет из себя учет приоритета операций. Для этого любое выражение раскладывается на слагаемые и множители. Далее сначала выполяются операции со скобками, затем с множителями, и в конце со слагаемыми. В терминах БНФ матемтическое выражение описывается так:

Оператор1 ::= '+' | '-'

Оператор2 ::= '*' | '/'

Множитель ::= Число | '(' Выражение ')'

Слагаемое ::= Множитель [Оператор2 Множитель]

Выражение ::= Слагаемое [Оператор1 Слагаемое]

Требование наличия скобок делает нашу грамматкику рекурсивной (на моменте вычисления множителя).

Программная часть.

Теперь определимся с программной частью. Непосредственно синтаксис БНФ будет разбирать синтаксический анализатор. Но с точки зрения грамматики выражение 2+2 является корректным, а 2 + 2 - нет, и для решения этой проблемы (обычно выражения с переносами строки и пробелами читаются легче) будет использоваться лексический анализатор. Его целью будет пропуск незначащих символов и извлечение лексемы (в нашей грамматике это может быть Число, Операция или одна из Скобок, которую он передаст на вход синтаксического анализатора.

Лексический анализатор.

Функция СледующийЛитерал(Литерал, ТекстЗапроса, ТекПоз)

    Если
ТекПоз <= СтрДлина(ТекстЗапроса) Тогда

       
// Пропустить пробелы
       
НезначащиеСимволы = " " + Символы.ПС + Символы.Таб;
        Пока
Найти(НезначащиеСимволы, Сред(ТекстЗапроса, ТекПоз, 1)) > 0 Цикл
           
ТекПоз = ТекПоз + 1;
        КонецЦикла;

       
// Извлечь литерал
       
ТекСимвол = Сред(ТекстЗапроса, ТекПоз, 1);

        Если
Найти("()*/+-", ТекСимвол) > 0 Тогда

           
Литерал = ТекСимвол;
           
ТекПоз = ТекПоз + 1;

        ИначеЕсли
ЭтоЦифра(ТекСимвол) Тогда

           
Литерал = ИзвлечьЧисло(ТекстЗапроса, ТекПоз);

        Иначе

            ВызватьИсключение
"Неизвестный символ в позиции " + Формат(ТекПоз, "ЧГ=0");

        КонецЕсли;

        Возврат Истина;

    Иначе

       
Литерал = Неопределено;
        Возврат Ложь;

    КонецЕсли;

КонецФункции

Функция
ИзвлечьЧисло(ТекстЗапроса, ТекПоз)

   
ТекСимвол = Сред(ТекстЗапроса, ТекПоз, 1);
   
Результат = "";

   
// Целая часть
   
Пока ЭтоЦифра(ТекСимвол) И ТекПоз <= СтрДлина(ТекстЗапроса) Цикл
       
ТекПоз = ТекПоз + 1;
       
Результат = Результат + ТекСимвол;
       
ТекСимвол = Сред(ТекстЗапроса, ТекПоз, 1);
    КонецЦикла;

   
// Дробная часть
   
Если ТекСимвол = "." Тогда
       
Результат = Результат + ".";
       
ТекПоз = ТекПоз + 1;
       
ТекСимвол = Сред(ТекстЗапроса, ТекПоз, 1);
        Пока
ЭтоЦифра(ТекСимвол) И ТекПоз <= СтрДлина(ТекстЗапроса) Цикл
           
ТекПоз = ТекПоз + 1;
           
Результат = Результат + ТекСимвол;
           
ТекСимвол = Сред(ТекстЗапроса, ТекПоз, 1);
        КонецЦикла;
    КонецЕсли;

    Возврат
Число(Результат);

КонецФункции

Функция
ЭтоЦифра(ТекСимвол)

    Возврат
ТекСимвол >= "0" И ТекСимвол <= "9";

КонецФункции

Синтаксический анализатор.

Теперь приведу функции синтаксического анализатора. Каждая из них соответствует элементу грамматики БНФ. Отмечу, что в примере этими функциями вычисляются реальные выражения, хотя в реальном парсере они будут всего лишь проверять корректность выражений в запросе. Также в коде отсутствует часть необходимых исключений (эти функции я выдергивал из парсера запросов, который обладает уже гораздо большим функционалом, поэтому частью исключений пришлось пожертвовать - но они вернутся в следующих статьях)

Функция Выражение(ТекЛитерал, ТекстЗапроса, ТекПоз) Экспорт

    Если
ТекЛитерал = Неопределено Тогда
       
// При первом вызове необходимо сдвинуть автомат на первую позицию
       
Если Не СледующийЛитерал(ТекЛитерал, ТекстЗапроса, ТекПоз) Тогда
            ВызватьИсключение
"Пустая строка";
        КонецЕсли;
    КонецЕсли;

   
Результат = Слагаемое(ТекЛитерал, ТекстЗапроса, ТекПоз);
    Пока Не
ТекЛитерал = Неопределено И Найти("+-", ТекЛитерал) > 0 Цикл
       
Литерал = ТекЛитерал;
       
СледующийЛитерал(ТекЛитерал, ТекстЗапроса, ТекПоз);
        Если
Литерал = "+" Тогда
           
Результат = Результат + Слагаемое(ТекЛитерал, ТекстЗапроса, ТекПоз);
        Иначе
           
Результат = Результат - Слагаемое(ТекЛитерал, ТекстЗапроса, ТекПоз);
        КонецЕсли;
    КонецЦикла;

    Возврат
Результат;

КонецФункции

Функция
Слагаемое(ТекЛитерал, ТекстЗапроса, ТекПоз)

   
Результат = Множитель(ТекЛитерал, ТекстЗапроса, ТекПоз);
    Пока Не
ТекЛитерал = Неопределено И Найти("*/", ТекЛитерал) > 0 Цикл
       
Литерал = ТекЛитерал;
       
СледующийЛитерал(ТекЛитерал, ТекстЗапроса, ТекПоз);
        Если
Литерал = "*" Тогда
           
Результат = Результат * Множитель(ТекЛитерал, ТекстЗапроса, ТекПоз);
        Иначе
           
Результат = Результат / Множитель(ТекЛитерал, ТекстЗапроса, ТекПоз);
        КонецЕсли;
    КонецЦикла;

    Возврат
Результат;

КонецФункции

Функция
Множитель(ТекЛитерал, ТекстЗапроса, ТекПоз)

    Если
ТекЛитерал = "(" Тогда

        Если
СледующийЛитерал(ТекЛитерал, ТекстЗапроса, ТекПоз) Тогда
           
Результат = Выражение(ТекЛитерал, ТекстЗапроса, ТекПоз);
            Если
ТекЛитерал = ")" Тогда
               
СледующийЛитерал(ТекЛитерал, ТекстЗапроса, ТекПоз);
            Иначе
                ВызватьИсключение
"Ожидается ) в позиции " + Формат(ТекПоз, "ЧГ=0");
            КонецЕсли;
        Иначе
            ВызватьИсключение
"Ожидается выражение в позиции " + Формат(ТекПоз, "ЧГ=0");
        КонецЕсли;

    ИначеЕсли
ЭтоЦифра(Сред(Строка(ТекЛитерал), 1, 1)) Тогда
       
Результат = ТекЛитерал;
       
СледующийЛитерал(ТекЛитерал, ТекстЗапроса, ТекПоз);
    Иначе
        ВызватьИсключение
"Неизвестный литерал в позиции " + Формат(ТекПоз, "ЧГ=0");
    КонецЕсли;

    Возврат
Результат;

КонецФункции

Скачать файлы

Наименование Файл Версия Размер
Обработка для теста парсера математических выражений
.epf 6,72Kb
04.12.13
19
.epf 0.1 6,72Kb 19 Скачать

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. juntatalor 62 04.12.13 17:44 Сейчас в теме
В функциях, которые в самой публикации, съелась половина кода.
Раскрасил "Разукрашкой", все Ок.
2. tsmgeorg@gmail.com 04.12.13 18:49 Сейчас в теме
Да, бывает, иногда весело отвлечься от повседневных будней, спасибо за статью
3. omut 04.12.13 19:46 Сейчас в теме
Увлекательно написано, автору спасибо :)

Небольшое замечание: если правильно понял, то вместо
Число ::= [Знак] Число (Число) [ Разделитель Число (Число) ]
должно быть "Число ::= [Знак] Цифра (Цифра) [ Разделитель Цифра (Цифра) ]"
8. juntatalor 62 04.12.13 23:18 Сейчас в теме
(3) omut, да, спасибо за внимательное чтение - поправил!
(5) andrewks, а вы попробуйте выполнить запрос "ВЫБРАТЬ .25 КАК Поле1". С точки зрения запросов 1С .25 - НЕ число.
9. andrewks 1273 04.12.13 23:47 Сейчас в теме
(8)
С точки зрения запросов 1С .25 - НЕ число.


зато "25." число ;)
juntatalor; +1 Ответить
10. juntatalor 62 05.12.13 00:00 Сейчас в теме
(9) andrewks, да, действительно, и что интересно - реализация функции ИзвлечьЧисло() понимает такие числа. Ошибка в записи синтаксиса, сейчас поправлю.
4. vandalsvq 1141 04.12.13 22:41 Сейчас в теме
Жду продолжения. Интересная тема
5. andrewks 1273 04.12.13 22:54 Сейчас в теме
"Число ::= [Знак] Цифра (Цифра) [ Разделитель Цифра (Цифра) ]"


а разве .25 не число?

целая часть необязательна, если она опущена, подразумевается 0

правильнее так:

Число ::= [Знак] Цифра (Цифра) [ Разделитель Цифра (Цифра) ] | [Знак] Разделитель Цифра (Цифра)
7. omut 04.12.13 23:08 Сейчас в теме
(5) andrewks, не число. Если вы используете такую запись в коде 1С, тогда, конечно... :)
6. andrewks 1273 04.12.13 23:00 Сейчас в теме
31. so-quest 130 11.12.13 06:26 Сейчас в теме
(6) andrewks, есть уже. нафиг только никому не нужно :)
11. baton_pk 399 05.12.13 13:37 Сейчас в теме
Шлёпну плюс собрату по (не)счастью :) Со школьных лет увлекаюсь синтаксическими разборами выражений. Вот сейчас тоже на досуге пилю парсер языка запросов с последующим исполнением.

Маленькое замечание по тексту:
Вы пишете "Синтаксический анализатор.", однако в коде одновременно с разбором производите и вычисление. В случае, если мы пишем простенький калькулятор - это сгодится, но раз мы замахнулись на запросы, то всё же на выходе Вашего анализатора должно быть дерево вычислений. Обратная польская запись - наше всё.

Если есть желание, тут можно посмотреть, что у меня получается:
https://github.com/dmpas/e8-query-parser/blob/master/query-driver.e8s

Буду рад услышать Ваше мнение :) Заодно прикладываю обработку погонять.
Прикрепленные файлы:
ЗапросПоТаблицамЗначений.epf
brr; Elisy; JohnyDeath; shakmaev; juntatalor; +5 Ответить
13. juntatalor 62 05.12.13 19:41 Сейчас в теме
(11) baton_pk, вычисление прикрутил, чтобы показать, что это действительно работает :)

Поделюсь и я тем, что уже есть. Сейчас столкнулся с тем, что для работы лексического анализатора уже нужен семантический - например, нужно знать количество параметров виртуальной таблицы, и их тип для корректной обработки.

Реализованный функционал:
Пакет запросов, запрос, описание запроса (по синтаксической диаграмме 1С), вложенные запросы
ВЫБОР ... КОГДА ...
ВЫРАЗИТЬ(... КАК) [Только для примитивных типов, для таблиц пока нет]
Все логические конструкции (В (включая вложенные запросы), ПОДОБНО, МЕЖДУ, ЕСТЬ, ССЫЛКА)
Да и много чего еще

Баги и нереализованное:
Простое выражение (например, имя поля, параметр или константа ИСТИНА / ЛОЖЬ) не считаются корректным логическим выражением. Обязательно надо указывать сравнение, например ГДЕ ИСТИНА - не работает, а ГДЕ 1 = 1 - работает.
Нет проверки на необходимость функции быть агрегатной
Да и еще куча всего. Зато есть динамический построитель таблиц базы данных.

Прикрепленные файлы:
КонструкторЗапросов9.epf
garik80; brr; baton_pk; +3 Ответить
16. baton_pk 399 06.12.13 08:53 Сейчас в теме
(13)
Посмотрел Вашу обработку - внушает :) Мы даже пишем почти одинаково :)

Лично я не вижу смысла производить семантический анализ текста на этапе его лексического разбора. Я бы оставил это уже на этап исполнения - когда мы знаем весь набор входящих данных.

Вы при разборе выражения указываете, считать его логическим или нет. У Вас, кстати, при разборе конструкции ВЫБОР не совсем верно отрабатывает проверка на логичность. Как сделано у Вас:

ВЫБОР КОГДА <тут разбираем логическое выражение> ТОГДА <тут разбираем нелогическое выражение> ....

Однако в выражении ТОГДА тоже может быть логическое выражение, если извне мы разбираем именно логическое выражение:

ГДЕ ВЫБОР КОГДА 1=1 ТОГДА ИСТИНА ИНАЧЕ ЛОЖЬ КОНЕЦ = ИСТИНА

В данном случае, пытаясь разобрать инструкцию ВЫБОР, Вы не знаете, должна она быть логической или нет, пока не дойдёте до знака сравнения.

С другой стороны, с точки зрения 1С такой запрос имеет место быть:

ВЫБРАТЬ 1 ГДЕ (1 + 3) = ИСТИНА


Лично я разбираю выражение независимо от его типа - проблемы с вычислением будут отрабатываться на этапе исполнения. Если мы выполняем отбор по условию ГДЕ или в конструкции КОГДА, то на этапе исполнения ожидаем получить там что-нибудь булёвое, и если не получаем - бросаем исключение.
juntatalor; +1 Ответить
17. juntatalor 62 06.12.13 09:13 Сейчас в теме
(16) baton_pk, с Вашими доводами согласен целиком и полностью.
Вообще у меня на каком-то этапе разбора выражений произошел кризис - я понял, что не могу автоматически отличить логическое выражение от математического. Приняв это как данность, я накрутил ручную установку флага "Логическое" и успокоился. Пока речь шла о простых условиях, все было нормально. Но сейчас уже есть ВЫБОР ... КОНЕЦ и параметры виртуальных таблиц. Сейчас уже всерьез задумался, что автоматическое определение типа выражения - логическое / математическое - это необходимость.
18. juntatalor 62 06.12.13 09:18 Сейчас в теме
(16) baton_pk, кстати, как Вам моя процедура ДобавитьИсточник()? Вроде бы достаточно неплохо обрабатывает соединения (ну, за исключением, как мы уже говорили, некоторой корявости с математикой / логикой).
baton_pk; +1 Ответить
19. baton_pk 399 06.12.13 10:36 Сейчас в теме
(18)
В смысле разбора я примерно так и думал его делать. У меня нет чёткого понимания, как это должно отрабатываться уже непосредственно при исполнении. Это влияет на порядок построения дерева, а это влияет на разработку непосредственно разбора.

Да, и ещё: у Вас обязательно наличие слова "КАК". Знаю я людей, которые патологически презирают это слово :):)

Ещё неясный момент с выборкой всех полей по "*". У Вас отрабатывается только "ВЫБРАТЬ * ИЗ Т1,Т2", когда вполне может быть запрос: "ВЫБРАТЬ Т1.Поле1, Т1.Поле2, Т2.* ИЗ Т1, Т2"
23. juntatalor 62 06.12.13 14:07 Сейчас в теме
(19) baton_pk, Насчет * - внес в TODO лист.

КАК обязательно только для вложенных запросов, для обычных таблиц нет.
25. baton_pk 399 06.12.13 14:31 Сейчас в теме
(23) я не только про таблицы, я ещё и про поля.
14. juntatalor 62 05.12.13 20:08 Сейчас в теме
(11) baton_pk, как вы серьезно к разработке подошли! Очень понравился такой "Отладочный" режим выполнения запросов. Изучаю Ваш труд и готовлю следующую публикацию. Хотел в ней уже начать разбираться непосредственно с запросами, но получается очень объемно, возможно, придется все же сначала полностью закончить с математическими выражениями.
15. baton_pk 399 05.12.13 22:07 Сейчас в теме
(14)
я сейчас размышляю над соединениями таблиц - там есть, над чем подумать. На этом пока заткнулся. Покуриваю стандарт SQL-92 - труд здоровенный, но некоторые вещи там описаны хорошо.

Завтра на работе посмотрю Ваш конструктор.
12. Yashazz 3042 05.12.13 19:00 Сейчас в теме
Йессс! Подобные публикации таки опровергают гнусное мнение, что "одинэснег - не программист". Спасибо!
20. German 872 06.12.13 10:51 Сейчас в теме
Парни GoldParser(x32) или Antlr. Зачем такие велосипеды? Все уже давно сделано в том числе написана грамматика для языка запросов 1С
JohnyDeath; awk; +2 Ответить
21. baton_pk 399 06.12.13 11:03 Сейчас в теме
(20) German,
я так понимаю, что у juntatalor интерес чисто академический - тут по-определению будут сплошь одни велосипеды.
22. comol 4170 06.12.13 11:16 Сейчас в теме
Эх... детство, отрочество, молодость....


(20) German, да. да... Такие крутяцкие программулены, изучаешь в каком формате им нужно семантику или синтаксис скармливать, пишешь правила и фигак оно всё парсит, и более того даже код на c++ генерит для парсера...

мы в школеунивере развлекались с Flex и Bison...
awk; juntatalor; German; +3 Ответить
28. awk 695 09.12.13 10:22 Сейчас в теме
(20) German, (22) comol, А мне javacc нравится..
24. tormozit 5689 06.12.13 14:09 Сейчас в теме
Я здесь был (подписался)
26. AllexSoft 06.12.13 17:57 Сейчас в теме
Интересно что получится в итоге....
27. juntatalor 62 06.12.13 19:31 Сейчас в теме
(26) AllexSoft, то, что обещано в пункте 3, конечно же! :-)
3. Создание обработки "Конструктор запросов" на управляемых формах

После выходных выложу вторую часть статьи. Под конец недели работы много, никак не допишу.
29. ignor 222 09.12.13 15:08 Сейчас в теме
30. so-quest 130 11.12.13 06:22 Сейчас в теме
Мои пять копеек - сравнение литералов - медленная операция. в своем сканере сдеала так - сперва весь поток преобразовывается в массив чисел (используется кодсимвола) и затем просто сравнение чисел. Но вообще-то предыдущие участники правы - детство все это - эффективнее чем автомат у тебя не получится, потребности помнить пробельный символы в твое задаче нет, выгоднее использовать типовые инструменты, чем изобретать свой лисапед. тем более для голдпарсера есть вывод кода сразу в 1С, без использования активХ.

Вот если бы ты для PEG парсера преобразователь нарисовал - было бы лучше...
32. juntatalor 62 11.12.13 10:07 Сейчас в теме
(30) so-quest, да уже столкнулся с тем, что сравнивать литералы действительно очень медленно. Пока что провел замеры различных алгоритмов, как ни странно, выигрывает Найти(ВесьАлфавит, ТекСимвол). Примерно равный результат дает перевод алфавита в Соответствие и сравнение литерала методом Соответствие.Получить(). Хуже Найти(ЗаглавныйАлфавит, Врег(ТекСимвол), перевод через КодСимвола с последующим сравнением числа и прямое сравнение символов.
С КодСимвола() все сложно. Не спорю, что если все перевести в числа, и потом сравнивать - работает быстрее, но эффективно это будет только если много раз парсить один и тот же запрос (тут встает вопрос - зачем?) - потому что на каждый новый запрос нужно будет создавать новый массив чисел, а это сильные временные затраты на КодСимвола (как-то уж очень неспешно она работает).
Вообще, убедился в очередной раз, что для критичных с точки зрения производительности процессов скриптовые языки подходят плохо. Нет высокоуровнего доступа к процессору и памяти, в результате чего код, который отрабатывает на C за микросекунды в 1С работает секунды (хотя, казалось бы - простая операция сравнения).
37. so-quest 130 12.12.13 07:44 Сейчас в теме
(32) Скорость и 1С это как селедка и шампанское. крайне редко вместе уживаются. Хотяб потому что операция сравнения простая только если знаешь тип.
(33) baton_pk, руками писать понимаемый код можно только пока работаешь один. когда начинаешь работать в команде - все же требуется использование типовых (либо признаных такими) инструментов. Просто потому что там уже решены проблемы со скоростями, обработкой ошибок и наработаны практики использования. Ты же не изобретаешь каждый раз УниверсальныйОтчет или не пишешь каждый день с ноля конвертацию данных.
Что касается голдпарсера - так это даже не смешно - нечего там изучать (тем более зная теорию ) - это же просто генератор таблиц для автоматов.

lesenoklenok; +1 Ответить
38. baton_pk 399 12.12.13 08:25 Сейчас в теме
(37) so-quest,
Просто потому что там уже решены проблемы со скоростями

Ага, помнится, на одном жёлтом неназываемом здесь форуме очень дико ругались на производительность GoldParse, ANTLR и иже с ними. Самому, к сожалению, пока не довелось сравнить скорости, потому в эту сторону рассуждать не буду.

Ты же не изобретаешь каждый раз УниверсальныйОтчет или не пишешь каждый день с ноля конвертацию данных

Боже упаси! :-D

нечего там изучать (тем более зная теорию )

Для меня "нечего там изучать" - это открыл, вбил, нажал, получил. Если за 5-10 минут у меня это не получилось, значит, надо всё-таки хоть чуть-чуть поизучать. В универсальном отчёте тоже вроде бы нечего изучать, ан нет - сам убил не один час своей жизни, объясняя людям, что это и как этим пользоваться.

это же просто генератор таблиц для автоматов

Ага, но итог-то требуется не в виде таблиц, а в виде автомата, работающего с этой таблицей на нужном языке.
Я понимаю, что тут есть незнание и кривость рук, но то.... код... который мне выдала эта штуковина, ни на что не годится.

Потому опять же, "нечего изучать" - Вы тут немножко лукавите всё-таки.

PS
руками писать понимаемый код можно только пока работаешь один

Нет, если следовать стандартам. В 1С их пока-что маловато и тем не следуют. Да и практика оценки кода (Code Review) тут совершенно никак не применяется :(.
Прикрепленные файлы:
Grammatika_yazyka_zaprosov_1C_8.2_goldparser_1.32.c
Grammatika_yazyka_zaprosov_1C_8.2_goldparser_1.32.cpp
40. so-quest 130 12.12.13 09:20 Сейчас в теме
(38) baton_pk, производительность ANTLR это конечно да... Та еще песня. По голдпарсеру - все от радиуса кривизны рук зависит. ничто не мешает переписать шаблон генерации так что бы скорость тебя удовлетворяла (на любом удобном тебе языке). Ручной парсер нужен там где граматику не сделать (лисп/схема (макросы чтения все портят)). Или сделать, но она неоправданно сложная станет (С++ или С). В случае с 1С - излишне.
Все вышеописаное - имхо.
И да - лучше все же flex\bison чем голдпарсер, ручной парсер.


Кстати, выложи свой парсер 1С - глянуть.
43. baton_pk 399 12.12.13 09:40 Сейчас в теме
(40) so-quest,
Прикладываю его старую версию на C++. Сейчас всё на чистый C переписаваю. У файла куча внешних зависимостей, но если Вам только код глянуть, то в самый раз. В добавок, вывод байт-кода тоже можно было бы отбросить.

Эта штука у меня без ошибок разобрала все общие модули УПП. Отрабатывает директивы препроцессора произвольной вложенности. Добавлена пара фишек от себя, в частности:

https://github.com/dmpas/e8-engine-examples/blob/master/0.2.4/pre-or-and.e8s
https://github.com/dmpas/e8-engine-examples/blob/master/0.2.4/assert.e8s
https://github.com/dmpas/e8-engine-examples/blob/master/0.2.4/altnames.e8s
Прикрепленные файлы:
Translator.cpp
33. baton_pk 399 11.12.13 10:15 Сейчас в теме
Не смог сдержать буйный интерес и поставил себе GoldParser. Неслабый инструмент, но требующий глубокого изучения.
Если стоит выбор, изучать теорию лексического разбора или изучать GoldParser, то конечно же лучше изучить GoldParser. Но если выбор в том, писать ли свой парсер, зная теорию лексического разбора, или изучать GoldParser с нуля, то я уж лучше напишу свой парсер сам :)

Приведу цифры:
На поставить(/посмотреть/потыркать/попробовать и т.д) GoldParser у меня ушло примерно 1.5-2 часа, чтобы понять, что это такое и с чем едят. Парсер языка 1С с преобразованием в байт-код я написал за 7 часов. Без байт-кода это как-раз бы и вышло 1.5-2 часа. Ну, если б я писал парсер хотя бы каждый месяц, я бы безусловно освоил и GoldParser, и его собратьев, но т.к. парсеры приходится писать крайне редко, а разбор математических конструкций я пишу чуть ли не с закрытыми глазами, а на выходе получаю код целиком и полностью мне известный, то буду писать парсеры руками.

Поэтому опять же, не ищите в статье практического смысла. Он тут исключительно академический.
34. WalterMort 311 11.12.13 14:42 Сейчас в теме
Уже писал нечто подобное (конструктор запроса УФ), да всё руки не доходят завершить. В целом, прочитать запрос в дерево полдела. Там ещё веселья добавляется в разного рода камнях. Преобразовать таблицу "связи" в конкретное выражение в тексте запроса, например, только на первый взгляд тривиальная задача.
baton_pk; +1 Ответить
35. Pashkatancor 69 12.12.13 03:52 Сейчас в теме
36. slavik27 10 12.12.13 07:06 Сейчас в теме
39. tormozit 5689 12.12.13 08:48 Сейчас в теме
Возможно кто то не знает, конструктор запроса я свой уже сделал в ИР http://devtool1c.ucoz.ru/index/konstruktor_zaprosa/0-38 . Если кто то захочет писать свой, то думаю мой код ему драматически сократит затраты по времени.
GoldParser на сервере мне не удалось использовать. Может быть кто то знает волшебный способ? Тогда бы до конструктора запроса под тонкую форму осталось часов 20-30.
Yasen; German; baton_pk; +3 Ответить
41. so-quest 130 12.12.13 09:21 Сейчас в теме
(39) tormozit, я тебе уже рекламировал свой шаблон генератора для голдпарсера, что помешало использовать?
42. tormozit 5689 12.12.13 09:27 Сейчас в теме
(41) Объектная модель GoldParser у тебя не воссоздана. Она у меня активно используется в коде конструктора запросов. Т.е. придется много кода переделывать необратимо, либо засорять и без того сложную логику ветвлениями "если парсер такой, то делаем так, иначе делаем так".
44. ikekoval 101 17.12.13 16:31 Сейчас в теме
Статья очень понравилась. Жду продолжения (подпись)
45. magolubev 30.12.13 12:53 Сейчас в теме
Вспомнил институтские годы, парсеры на Lex/Yacc...
По делу - согласен с baton_pk, необходимо промежуточное представление программы в форме обратной польской записи
46. lesenoklenok 23 28.01.14 09:47 Сейчас в теме
Очень интересная статья, подробно описано.
47. baton_pk 399 20.02.14 08:49 Сейчас в теме
(0) Где обещанное продолжение??
48. so-quest 130 22.11.14 21:38 Сейчас в теме
Моя попытка продолжения http://www.cyberforum.ru/1c-custom/thread1307974.html#post6887051 - собираю критику к 1 главе.
Оставьте свое сообщение

См. также

Treemapping — способ визуализации данных древовидной структуры. Карта-схема дерева

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Математика и алгоритмы Работа с интерфейсом

Предлагается ознакомиться с редким способом графического представления иерархических данных. Приводится алгоритм формирования и пример реализации.

18.02.2020    1698    randomus    17       

Программы для исполнения 54-ФЗ Промо

С 01.02.2017 контрольно-кассовая техника должна отправлять электронные версии чеков оператору фискальных данных - правила установлены в 54-ФЗ ст.2 п.2. Инфостарт предлагает подборку программ, связанных с применением 54-ФЗ, ККТ и электронных чеков.

[После]Новогодние задачи

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Математика и алгоритмы

Совсем немного времени осталось до того момента, когда отзвучат куранты, шампанское будет выпито, мандарины съедены, и даже оливье закончится. Возникнет вопрос: чем бы занять неожиданно появившееся свободное время?

30.12.2019    1696    Alxby    23       

Новый раздел на Инфостарте - Electronic Software Distribution Промо

Инфостарт напоминает: на нашем сайте можно купить не только ПО, связанное с 1С. В нашем арсенале – ESD-лицензии на ПО от ведущих вендоров: Microsoft, Kaspersky, ESET, Dr.Web, Аскон и другие.

  • Низкие цены, без скрытых платежей и наценок
  • Оперативная отгрузка
  • Возможность оплаты с личного счета (кешбек, обмен стартмани на рубли и т.п.)
  • Покупки идут в накопления для получения скидочных карт лояльности Silver (5%) и Gold (10%)

"Хочу универсально!" [Часть 1]

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Математика и алгоритмы Практика программирования Разработка

Сентябрьская серия статей про то, как начинающий разработчик Вася проходит путь от простой задачки к созданию своего механизма. На этот раз - открытие значения из текущей колонки.

02.09.2019    7053    SeiOkami    35       

Иерархия без "В ИЕРАРХИИ"

Статья Программист Нет файла v8 Бесплатно (free) Математика и алгоритмы

Говорится о том, как эффективно представлять иерархию в СУБД, как получать и использовать эти представления при решении задач в запросной технике. Уточняются и дополняются запросы из статьи "Уровни, глубина, прародители, циклы и аналоги запросом" [https://infostart.ru/public/160707/].

22.08.2019    8285    ildarovich    19       

Программы для исполнения 488-ФЗ: Маркировка товаров Промо

1 января 2019 года вступил в силу ФЗ от 25.12.2018 № 488-ФЗ о единой информационной системе маркировки товаров с использованием контрольных (идентификационных) знаков, который позволяет проследить движение товара от производителя до конечного потребителя. Инфостарт предлагает подборку программ, связанных с применением 488-ФЗ и маркировкой товаров.

EnterpriseData – часть 3. Загрузка данных, идентификация объектов

Статья Программист Нет файла v8 v8::УФ 1cv8.cf ОС Бесплатно (free) Практика программирования Математика и алгоритмы Перенос данных из 1C8 в 1C8 Разработка

Основные этапы загрузки данных через EnterpriseData. Идентификация объектов загружаемых полностью и по ссылке. Приведены схемы процессов загрузки данных. Описание основных операций и обработчиков. Перечень процедур БСП, используемых при загрузке данных, структура «КомпонентыОбмена».

22.08.2019    7611    ids79    7       

Обработчики событий при записи объектов. Зачем и что за чем?

Статья Программист Нет файла v8 Бесплатно (free) Математика и алгоритмы

Программисту, имеющему немного опыта на платформе 1С 8.3, бывает сложно разобраться: ПередЗаписью, ПриЗаписи, ПослеЗаписи, на сервере, на клиенте, в модуле формы, в модуле объекта.... Эта шпаргалка была создана в процессе обучения и реального опыта с целью разложить всё по полочкам, чтобы было четкое понимание в каком случае какой обработчик нужно использовать и в какой последовательности они запускаются при записи и проведении документов. Данная статья будет полезна в большей степени начинающим разработчикам. Но и опытным позволит освежить информацию, упорядочить её.

25.07.2019    23999    4    AlbinaAAA    24       

Готовые переносы данных из различных конфигураций 1C Промо

Рекомендуем готовые решения для переноса данных из различных конфигураций 1C. C техподдержкой от разработчиков и гарантией от Инфостарт.

Как проводятся документы в типовых конфигурациях от 1С

Статья Программист Нет файла v8::ОУ ERP2 УТ11 Россия УУ Windows Бесплатно (free) Математика и алгоритмы Практика программирования Разработка

В свое время, когда только начинал шаги в 1С и изучал, как проводятся документы в конфигурациях на платформе 1С по книге "Разработка управляемого интерфейса" (Хрусталева Е.Ю.), и там были представлены примеры совсем далекие от того, как сейчас проводятся документы в современных конфигурациях от 1С.

24.07.2019    21099    skv_79    35       

FizzBuzz на 1С. Чем короче, тем веселее. Варианты принимаются...

Статья Программист Нет файла v8 Бесплатно (free) Практика программирования Математика и алгоритмы Разработка

Мне было скучно, я не мог себя заставить написать ничего полезного. И читал статью на Хабре. Потом я читал комментарии, а потом... нет я не ушел смотреть котиков на ютюбе. Я решил сделать несколько решений задачки FizzBuzz на 1С, с целью "чем короче, тем лучше". Прошу сильно не пинать, это просто развлечение для вечера.

24.07.2019    3874    vandalsvq    16       

1C:Предприятие для программистов: Расчетные задачи (зарплата). Онлайн-интенсив с 01 по 17 июня 2020 г. Промо

Данный онлайн-курс предусматривает изучение механизмов платформы “1С:Предприятие”, которые предназначены для автоматизации периодических расчетов, а именно - для расчета зарплаты. Курс предназначен для тех, кто уже имеет определенные навыки конфигурирования и программирования в системе “1С:Предприятие”, а также для опытных пользователей прикладного решения “1С:Зарплата и управление персоналом” и прочих прикладных решений, в которых реализован функционал расчета зарплаты.

4900 рублей

Управление качеством кода

Статья Программист Руководитель проекта Нет файла v8 Бесплатно (free) Математика и алгоритмы Рефакторинг и качество кода

О SonarQube, АПК, EDT. Какие преимущества дает их использование. Для каких команд подходит.

22.07.2019    11675    Stepa86    33       

Что делает "В ИЕРАРХИИ" в запросе?

Статья Программист Нет файла v8 Бесплатно (free) Математика и алгоритмы

Описание действий платформы 1С при использовании конструкции "В ИЕРАРХИИ" в запросах.

16.07.2019    13406    YPermitin    34       

Подборка решений для взаимодействия со ФГИС «Меркурий» Промо

С 1 июля 2019 года все компании, участвующие в обороте товаров животного происхождения, должны перейти на электронную ветеринарную сертификацию (ЭВС) через ФГИС «Меркурий». Инфостарт предлагает подборку программ, связанных с этим изменением.

Создание отчетов с помощью СКД - основные понятия и элементы

Статья Программист Нет файла v8 v8::СКД Бесплатно (free) Практика программирования Математика и алгоритмы

Основные принципы работы СКД. Понятия схемы компоновки и макета компоновки. Описание основных элементов схемы компоновки: наборы данных, поля, вычисляемые поля, ресурсы, параметры.

25.06.2019    31928    ids79    17       

Реализуем Стек, Очередь и Приоритетную очередь в 1С

Статья Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) Практика программирования Математика и алгоритмы

В статье рассматриваются способы реализации таких абстрактных структур данных, как стек, очередь и приоритетная очередь, используя готовые типы данных 1С. Выявляются "узкие" места, сложные моменты в реализации и сравнивается скорость работы.

24.06.2019    10958    RonX01    65       

Голосование за доклады на INFOSTART MEETUP Kazan - до 25 февраля. Промо

Выбирайте и голосуйте за самые интересные доклады! Лучшие из лучших попадут в окончательную программу казанского митапа. Оставить свой голос можно до 25 февраля 2020 года.

Организация хранения промежуточных данных

Статья Программист Нет файла v8 Бесплатно (free) Математика и алгоритмы

Организация хранения промежуточных данных в процедуре сверки.

29.05.2019    2846    scientes    1       

Вычисление 200 тысяч знаков числа pi

Статья Программист Нет файла v8 Россия Бесплатно (free) Математика и алгоритмы

В статье рассматриваются возможности платформы выполнять сверхточные вычисления без использования сложных алгоритмов и внешних компонент на примере вычисления числа pi.

28.05.2019    5205    Oleg_nsk    96       

​​​​​​​CorelDRAW Graphics Suite 2019 Промо

CorelDRAW – пакет профессиональных инструментов для редактирования фотографий, разработки дизайна, создания макетов страниц и векторных иллюстраций

Регистры накопления. Виртуальные таблицы. Часть №1: Обороты

Статья Программист Нет файла v8 1cv8.cf Бесплатно (free) Практика программирования Математика и алгоритмы Разработка

Описание работы платформы 1С:Предприятие 8.2 с виртуальной таблицей "Обороты" регистров накопления.

20.05.2019    16462    YPermitin    7       

Даем названия переменным: как префиксы экономят наше время

Статья Программист Стажер Внешняя обработка (ert,epf) v8 Бесплатно (free) Практика программирования Математика и алгоритмы Разработка

Понятные названия переменных экономят время и силы разработчика : в начале, когда мы даём названия переменным, в процессе развития разработки, когда мы "на лету" понимаем назначение той или иной переменной, в конце, когда мы передаём разработку на поддержку других программистов, сами переходя к новым разработкам

06.05.2019    4559    Designer1C    81       

INFOSTART MEETUP Kazan. 13 марта 2020 г. Промо

Инфостарт продолжает путешествие по России. Следующая остановка - Казань. Тема мероприятия - управление и технологии автоматизации учета на платформе "1С: Предприятие". Ждем всех: докладчиков и участников! Стоимость участия - 5 500 рублей. Цена действительна до 30.01.2020

5 500

Заметки по SQL: Срез последних - аналог запроса

Статья Программист Нет файла v8 1cv8.cf Россия Бесплатно (free) Математика и алгоритмы Практика программирования

В статье описывается создание среза последних данных средствами классического языка запросов. Причем метод построения запроса был разработан еще во времена, когда автор работал с СУБД Oracle 9i и программировал на PL SQL. Основная идея заключается преобразовании запроса с подзапросом, в запрос без подзапроса (в примерах описывается преобразование до двух вложенных подзапросов). Запросы тестировались на реальных базах данных. Платформа - 1С:Предприятие 8.3 (8.3.10.2561).

15.01.2019    8011    IVC_goal    7       

Управление ИТ-проектами. Модуль 2: продвинутый онлайн-курс по классическим методам управления проектами. Вебинары проходят с 12 марта по 11 июня 2020 года. Промо

Продвинутый онлайн-курс по классическому управлению ИТ-проектами позволит слушателям освоить инструменты из PMBoK® и 1С:Технологии корпоративного внедрения и научиться их применять для проектов любого масштаба. Курс включает в себя 12 вебинаров и 12 видеолекции, разбор кейсов и рекомендации экспертов по проектам слушателей. Ведущая курса - Мария Темчина.

от 13000 рублей

Автоматические и управляемые блокировки применительно к типовым конфигурациям 1С

Статья Программист Нет файла v8 v8::blocking 1cv8.cf Бесплатно (free) Математика и алгоритмы Практика программирования

Основные принципы работы с режимами автоматических и управляемых блокировок в 1С Предприятие 8. Теория и применение в типовых конфигурациях: БП, УТ, ЕРП

10.11.2018    26405    ids79    40       

Подборка программ для взаимодействия с ЕГАИС Промо

ЕГАИС (Единая государственная автоматизированная информационная система) - автоматизированная система, предназначенная для государственного контроля за объёмом производства и оборота этилового спирта, алкогольной и спиртосодержащей продукции. Инфостарт рекомендует подборку проверенных решений для взаимодействия с системой.

Основные понятия и механизмы оптимизации клиент-серверного взаимодействия в 1C

Статья Программист Нет файла v8 Россия Бесплатно (free) Математика и алгоритмы Практика программирования

У многих начинающих 1С программистов часто возникают вопросы про клиент-серверное взаимодействие в 1С и чтобы разобраться в непростых механизмах платформы, необходимо понять, что же такое контекст, для чего предназначены директивы компиляции, что представляют собой контекстные/внеконтекстные вызовы и как наиболее оптимально описывать прикладные задачи в модулях управляемых форм.

23.08.2018    29868    Rain88    46       

Теорема номер тринадцать

Статья Программист Нет файла v8 Бесплатно (free) Математика и алгоритмы

Использование математических методов для языка запросов.

15.03.2018    10438    vasilev2015    24       

Сдача регламентированной отчетности из программ 1С Промо

Сдача регламентированной отчетности из программ "1С" во все контролирующие органы без выгрузок и загрузок в другие программы. Для групп компаний действуют специальные предложения.

от 1500 руб.

Введение в CI для 1С

Статья Программист Нет файла v8 Россия Бесплатно (free) Математика и алгоритмы

Значение роли тестирования при разработке ПО трудно переоценить, его применение позволяет повысить надёжность продукта и улучшить качество кода. Для продуктов для платформы 1С:Предприятие существует ряд инструментов для проведения тестирования, в том числе и от самого вендора. Но, также появились открытые инструменты, реализующие мировые практики проведения тестирования (проверки продукта), поддерживаемые сообществом. В этой статье описаны базовые принципы, которые необходимо понимать перед началом применения этих инструментов.

21.11.2017    21124    real_MaxA    22       

Как работает серверный вызов в 1С

Статья Программист Нет файла v8::УФ Бесплатно (free) Математика и алгоритмы

Клиент-серверная архитектура заложена в платформе изначально — со времен «1С:Предприятие 8.0». Однако при разработке на 8.0 и 8.1 о разделении кода на клиентскую и серверную часть можно было не заботиться, поскольку на клиенте (на толстом клиенте) был доступен тот же функционал, что и на сервере. Всё изменилось с выходом платформы «1С:Предприятие 8.2», когда появился тонкий клиент. Теперь на клиенте доступен один функционал, на сервере — другой. Клиент и сервер «общаются» между собой с помощью серверного вызова. Конечно, это усложнило процесс разработки, но с другой стороны – можно создавать более оптимальные (быстрые) решения, поскольку все сложные задачи выполняются на сервере.

18.11.2017    48800    pahich    79